Excel สูตรแปลงตัวเลขเป็นตัวหนังสือหรือตัวอักษรภาษาอังกฤษ

Share

จากบทความก่อนนี้ Excel สูตรแปลงตัวเลขเป็นตัวหนังสือหรือตัวอักษรภาษาไทยด้วย BAHTTEXT() ผมได้แนะวิธีการแปลงตัวเลขเป็นตัวอักษรหรือคำอ่านที่เป็นภาษาไทยไปแล้ว ด้วยการใช้ BAHTTEXT() เพื่อนำไปใช้กับงานอย่างบัญชี ออก Invoice หรือ PO หรือ พิมพ์เช็ค บทความนี้จะเป็นการแปลงตัวเลขเป็นตัวอักษรคำอ่านภาษาอังกฤษกันบ้างครับ

โปรแกรม Excel จะไม่มีฟังก์ชันมาให้ใช้งานเหมือนอย่างการแปลงตัวเลขเป็นตัวอักษรคำอ่านภาษาไทยนะครับ เราต้องสร้างฟังก์ชันขึ้นมาใช้งานเองครับด้วย Microsoft Visual Basic for Applications ที่มาพร้อมกับ Excel ซึ่งโค้ดคำสั่งผมเอามาจาก https://support.microsoft.com แล้วนำมาปรับเพื่อให้สามารถใช้ได้กับหน่วยเงินของไทย

เริ่มต้นสร้างฟังก์ชันแปลงตัวเลขเป็นคำอ่านภาษาอังกฤษ

ก่อนอื่นเปิดโปรแกรม Excel ขึ้นมาก่อน แล้วกดปุ่ม ALT + F11 บนคีย์บอร์ดเพื่อเปิด Visual Basic Editor ขึ้นมา จากนั้นไปที่เมนู Insert => Module ดังภาพด้านล่าง

Excel สูตรแปลงตัวเลขเป็นตัวหนังสือหรือตัวอักษรภาษาอังกฤษ

จากนั้น Copy โค้ดด้านล่างนี้ไปวางที่หน้าต่างด้านขวา ดังภาพด้านบน

Option Explicit
'Main Function
Function SpellNumber(ByVal MyNumber)
    Dim Dollars, Cents, Temp
    Dim DecimalPlace, Count
    ReDim Place(9) As String
    Place(2) = " Thousand "
    Place(3) = " Million "
    Place(4) = " Billion "
    Place(5) = " Trillion "
    ' String representation of amount.
    MyNumber = Trim(Str(MyNumber))
    ' Position of decimal place 0 if none.
    DecimalPlace = InStr(MyNumber, ".")
    ' Convert cents and set MyNumber to dollar amount.
    If DecimalPlace > 0 Then
        Cents = GetTens(Left(Mid(MyNumber, DecimalPlace + 1) & _
                  "00", 2))
        MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))
    End If
    Count = 1
    Do While MyNumber <> ""
        Temp = GetHundreds(Right(MyNumber, 3))
        If Temp <> "" Then Dollars = Temp & Place(Count) & Dollars
        If Len(MyNumber) > 3 Then
            MyNumber = Left(MyNumber, Len(MyNumber) - 3)
        Else
            MyNumber = ""
        End If
        Count = Count + 1
    Loop
    Select Case Dollars
        Case ""
            Dollars = "No Baht"
        Case "One"
            Dollars = "One Baht"
         Case Else
            Dollars = Dollars & "Baht"
    End Select
    Select Case Cents
        Case ""
            Cents = " Only"
        Case "One"
            Cents = " and One Satang"
              Case Else
            Cents = " and " & Cents & " Satang"
    End Select
    SpellNumber = Dollars & Cents
End Function

Function SpellNumber2(ByVal MyNumber)
    Dim Dollars, Cents, Temp
    Dim DecimalPlace, Count
    ReDim Place(9) As String
    Place(2) = " Thousand "
    Place(3) = " Million "
    Place(4) = " Billion "
    Place(5) = " Trillion "
    ' String representation of amount.
    MyNumber = Trim(Str(MyNumber))
    
    ' Position of decimal place 0 if none.
    DecimalPlace = InStr(MyNumber, ".")
    ' Convert cents and set MyNumber to dollar amount.
    If DecimalPlace > 0 Then
        Cents = Left(Mid(MyNumber, DecimalPlace + 1) & "00", 2)
        MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))
    End If
    Count = 1
    Do While MyNumber <> ""
        Temp = GetHundreds(Right(MyNumber, 3))
        If Temp <> "" Then Dollars = Temp & Place(Count) & Dollars
        If Len(MyNumber) > 3 Then
            MyNumber = Left(MyNumber, Len(MyNumber) - 3)
        Else
            MyNumber = ""
        End If
        Count = Count + 1
    Loop
    Select Case Dollars
        Case ""
            Dollars = "No Bahts"
        Case "One"
            Dollars = "One Baht"
         Case Else
            Dollars = Dollars & " Bahts"
    End Select
    Select Case Cents
        Case ""
            Cents = " Only"
        Case "One"
            Cents = " and One "
        Case Else
            Cents = " and " & Cents & "/100"
    End Select
    SpellNumber2 = Dollars & Cents
End Function
      
' Converts a number from 100-999 into text
Function GetHundreds(ByVal MyNumber)
    Dim Result As String
    If Val(MyNumber) = 0 Then Exit Function
    MyNumber = Right("000" & MyNumber, 3)
    ' Convert the hundreds place.
    If Mid(MyNumber, 1, 1) <> "0" Then
        Result = GetDigit(Mid(MyNumber, 1, 1)) & " Hundred "
    End If
    ' Convert the tens and ones place.
    If Mid(MyNumber, 2, 1) <> "0" Then
        Result = Result & GetTens(Mid(MyNumber, 2))
    Else
        Result = Result & GetDigit(Mid(MyNumber, 3))
    End If
    GetHundreds = Result
End Function
      
' Converts a number from 10 to 99 into text.
Function GetTens(TensText)
    Dim Result As String
    Result = ""           ' Null out the temporary function value.
    If Val(Left(TensText, 1)) = 1 Then   ' If value between 10-19...
        Select Case Val(TensText)
            Case 10: Result = "Ten"
            Case 11: Result = "Eleven"
            Case 12: Result = "Twelve"
            Case 13: Result = "Thirteen"
            Case 14: Result = "Fourteen"
            Case 15: Result = "Fifteen"
            Case 16: Result = "Sixteen"
            Case 17: Result = "Seventeen"
            Case 18: Result = "Eighteen"
            Case 19: Result = "Nineteen"
            Case Else
        End Select
    Else                                 ' If value between 20-99...
        Select Case Val(Left(TensText, 1))
            Case 2: Result = "Twenty "
            Case 3: Result = "Thirty "
            Case 4: Result = "Forty "
            Case 5: Result = "Fifty "
            Case 6: Result = "Sixty "
            Case 7: Result = "Seventy "
            Case 8: Result = "Eighty "
            Case 9: Result = "Ninety "
            Case Else
        End Select
        Result = Result & GetDigit _
            (Right(TensText, 1))  ' Retrieve ones place.
    End If
    GetTens = Result
End Function
     
' Converts a number from 1 to 9 into text.
Function GetDigit(Digit)
    Select Case Val(Digit)
        Case 1: GetDigit = "One"
        Case 2: GetDigit = "Two"
        Case 3: GetDigit = "Three"
        Case 4: GetDigit = "Four"
        Case 5: GetDigit = "Five"
        Case 6: GetDigit = "Six"
        Case 7: GetDigit = "Seven"
        Case 8: GetDigit = "Eight"
        Case 9: GetDigit = "Nine"
        Case Else: GetDigit = ""
    End Select
End Function

เมื่อวางโค้ดคำสั่งเสร็จแล้วกลับไปที่โปรแกรม Excel ครับ ซึ่งการเรียกใช้งานก็ทำได้ง่าย ๆ เหมือนเรียกใช้ฟังก์ชันอื่น ๆ ทั่วไป โดยโค้ดคำสั่งนี้จะมี 2 ฟังก์ชันให้เลือกใช้งานคือ SpellNumber() และ SpellNumber2()

รูปแบบของฟังก์ SpellNumber() จะเป็นดังนี้

SpellNumber(ตัวเลขที่ต้องแปลง หรือ Cell ที่ต้องการ)

หรือ

SpellNumber2(ตัวเลขที่ต้องแปลง หรือ Cell ที่ต้องการ)

การเรียกใช้คลิกไปที่ Cell ที่ต้องการใส่สูตรแล้วพิมพ์ = SpellNumber(100.50) หรือ = SpellNumber(A1) ซึ่งทั้งสองฟังก์ชันแตกต่างกันตรงที่คำอ่านในส่วนของสตางค์ ดังภาพด่านล่าง

Excel สูตรแปลงตัวเลขเป็นตัวหนังสือหรือตัวอักษรภาษาอังกฤษ

สำหรับบทความการแปลงตัวเลขเป็นตัวอักษรคำอ่านภาษาอังกฤษในโปรแกรม Excel ก็มีเพียงเท่านี้ครับง่าย ๆ ลองเอาไปปรับใช้ในการทำงานดูครับ จะช่วยให้เราทำงานได้ง่ายขึ้น รวดเร็วขึ้น และลดความผิดพลาดจากการพิมพ์เองไปได้เยอะครับ ถ้าบทความนี้มีความผิดพลาดประการใดก็ขออภัยด้วยครับ ถ้าไม่เป็นการรบกวนมากเกินไปก็กระซิบบอกผมก็ได้ครับจะได้แก้ไขให้ถูกต้อง ไว้เจอกันบทความหน้าครับ

บทความที่เกี่ยวข้อง